Hi Mike,
Not sure, but one thing you can do is turn on "debug mode" in the Output menu and then you can see the intermediate calculations that go into the calculation as seen here:
Line: 271 Intermediate Analytical Sensitivity Calculations (nominal beam = 1):
Element/Xray ti ka ti ka ti ka ti ka ti ka
Bgd Count/Sec 1.0 2.6 3.4 .8 1.4
Bgd CountTime 1920.00 1920.00 1920.00 1920.00 1920.00
Bgd Raw Count 381085.1010769.1315427. 302595. 529365.
Peak Cnt/Sec 1.0 2.6 3.4 .8 1.4
Peak Cnt Time 1920.00 1920.00 1920.00 1920.00 1920.00
Peak Raw Count 380952.1014290.1315704. 302399. 531793.
And in case it helps, here is the code used for the calculation:
Function ConvertAnalyticalSensitivity2(datarow As Integer, chan As Integer, sample() As TypeSample) As Single
' Calculate percent error for a single element
ierror = False
On Error GoTo ConvertAnalyticalSensitivity2Error
Dim temp1 As Single, temp2 As Single
Dim temp3 As Single, temp4 As Single
ConvertAnalyticalSensitivity2! = 0#
' Init debug variables
bgdtime! = 0#
bgdcount! = 0#
peakcount! = 0#
' Calculate
If sample(1).BgdData(datarow%, chan%) < 0# Then Exit Function
If sample(1).OnTimeData!(datarow%, chan%) <= 0# Then Exit Function
' Determine background count time for unknown
If sample(1).BackgroundTypes%(chan%) <> 1 Then ' 0=off-peak, 1=MAN, 2=multipoint
' 0=linear, 1=average, 2=high only, 3=low only, 4=exponential, 5=slope hi, 6=slope lo, 7=polynomial, 8=multi-point
If sample(1).OffPeakCorrectionTypes%(chan%) = 2 Then
bgdtime! = sample(1).HiTimeData!(datarow%, chan%) ' high only
ElseIf sample(1).OffPeakCorrectionTypes%(chan%) = 3 Then
bgdtime! = sample(1).LoTimeData!(datarow%, chan%) ' low only
Else
bgdtime! = sample(1).HiTimeData!(datarow%, chan%) + sample(1).LoTimeData!(datarow%, chan%) ' all other off peak types
End If
Else
bgdtime! = sample(1).OnTimeData!(datarow%, chan%) ' use on-peak time for MAN
End If
If bgdtime! = 0# Then Exit Function
' De-normalize unknown peak counts for time and beam (use corrected peak intensity + background for greater accuracy)
peakcount! = (sample(1).CorData!(datarow%, chan%) + sample(1).BgdData!(datarow%, chan%)) * sample(1).OnTimeData!(datarow%, chan%)
If peakcount! = 0# Then Exit Function
If Not sample(1).CombinedConditionsFlag% Then
Call DataCorrectDataBeamDrift2(peakcount!, sample(1).OnBeamData!(datarow%, chan%)) ' use OnBeamData in case of aggregate intensity calculation (average aggregate beam)
If ierror Then Exit Function
Else
Call DataCorrectDataBeamDrift2(peakcount!, sample(1).OnBeamDataArray!(datarow%, chan%)) ' use OnBeamDataArray in case of aggregate intensity calculation (average aggregate beam)
If ierror Then Exit Function
End If
' De-normalize unknown background counts for time and beam
bgdcount! = sample(1).BgdData(datarow%, chan%) * bgdtime!
If bgdcount! = 0# Then Exit Function
If Not sample(1).CombinedConditionsFlag% Then
Call DataCorrectDataBeamDrift2(bgdcount!, sample(1).OnBeamData(datarow%, chan%)) ' use OnBeamData in case of aggregate intensity calculation (use average aggregate beam)
If ierror Then Exit Function
Else
Call DataCorrectDataBeamDrift2(bgdcount!, sample(1).OnBeamDataArray!(datarow%, chan%)) ' use OnBeamDataArray in case of aggregate intensity calculation (use average aggregate beam)
If ierror Then Exit Function
End If
' Check for anomalies
If sample(1).OnTimeData!(datarow%, chan%) <= 0# Then Exit Function
If bgdtime! <= 0# Then Exit Function
temp1! = peakcount! / sample(1).OnTimeData!(datarow%, chan%) ^ 2
temp2! = bgdcount! / bgdtime! ^ 2
temp3! = peakcount! / sample(1).OnTimeData!(datarow%, chan%)
temp4! = bgdcount! / bgdtime!
If temp1! + temp2! < 0# Then Exit Function
If temp3! - temp4 = 0# Then Exit Function
ConvertAnalyticalSensitivity2! = 100# * Sqr(temp1! + temp2!) / (temp3! - temp4)
Exit Function
' Errors
ConvertAnalyticalSensitivity2Error:
MsgBox Error$, vbOKOnly + vbCritical, "ConvertAnalyticalSensitivity2"
ierror = True
Exit Function
End Function
Are you asking about trace elements because my take is that the analytical sensitivity calculation from Love-Scott is only useful for minor and major element concentrations?